OS X Folder Action to Send (Ascent) KML Data to Google Maps

OS X Folder Action to Send (Ascent) KML Data to Google Maps

Ascent is, as I've said before, what Garmin's Training Center should be. However, despite the plethora of enhancements over the past few months, the app is still not scriptable and doesn't have that whole Web 2.0/blogging/social networking goodness concept built into it.

Since it exports KML and natively integrates with Google Earth now, it seemed strange that it doesn't integrate more with Google Maps. To remedy this, I've built a small AppleScript folder action that has some of this functionality, provided you've got a web-space you can "scp" into.

First, you'll need to download the script (KMLtoGoogleMaps.scpt). Since it relies on the ability to scp data to a directory in your web space that is the accessible directly via a URL, you'll need to edit the script and change the variables ssh_dest and kml_URL to something that makes sense for you setup. The script also relies on your scp/ssh setup using certificates without passphrases. There are notes in the script if you need to work with passwords or passphrases, tho.

Next, create a folder and attach this script. Go to Ascent and save out a KML. NOTE: Google Maps KML integration does not like spaces in filenames, so make sure there are no spaces. (If I get enough requests, I'll mod the script to handle this automagically.)

If all went well, you'll see a Safari page with Google Maps and your route displayed. You can then use the Google Maps tools to do various things with the route.

Please report any problems with the script, revisions to the script, or requests for enhancements to the script in the comments.

Script code after the jump.

Enjoy!

--

--        File: KMLtoGoogleMaps.scpt

--     Version: 1.0

--      Author: boB Rudis (my first name at rudis dot net)

--    Web Site: http://www.rudis.net/

-- Description: Primarily written to work in conjunction with Ascent (http://www.montebellosoftware.com/).

--

--              This script is a folder action and will take any KML file placed into it and 

--              upload it to your personal web space via "scp" and then display it in Google Maps.

-- 

--              You need to set "ssh_dest" to your destination directory specification and

--              kml_URL to where Google Maps can find the file that was copied.

--

--              It also assumes you've got cert-based ssh enabled (without a passphrase).

--              Look here (http://forums.macosxhints.com/archive/index.php/t-49532.html) for info on

--              how to adjust for a password or non-blank passphrase.

--

--              You can use the "Link to the page" on the resultant map display to share the

--              route/route data with others.

--

--       Notes: Pretty much zero error checking. If folks want this to be more robust, just

--              let me know

--

property extension_list : {"kml"}
on adding folder items to thisFolder after receiving addedItems

    set ssh_dest to "user@example.com:/path/to/file" -- CHANGE ME!

    set kml_URL to "http://www.example.org/path/to/file/" -- CHANGE ME!

    tell application "Finder"

        repeat with i from 1 to number of items in addedItems

            set anItem to item i of addedItems

            set the item_info to the info for anItem

            if (the name extension of the item_info is in the extension_list) then

                do shell script "/usr/bin/scp -B -q " & quoted form of POSIX path of anItem & " " & ssh_dest

                tell application "Safari"

                    activate

                    make new document at end of documents

                    set URL of document 1 to ("http://maps.google.com/maps?f=q&q=" & kml_URL & (name of item_info))

                end tell

            end if

        end repeat

    end tell

end adding folder items to

2766 reads |

Tags: 2007, ascent, Fitness, Google Maps, kml, os x, Programming